我是【桃大喵学习记】，欢迎大家关注哟~，每天为你分享职场办公软件使用技巧干货！

——首发于微信号：桃大喵学习记

今天跟大家分享的是Excel新函数TOROW,它不仅仅可以将表格数据转换成一行显示，还是新一代超级查找函数！数据查找查找快、准、狠！效率爆表，完胜很多常用的查找函数。

TOROW函数介绍

功能：将二维数组转化成一行数据

语法：=TOROW(数组,[忽略特殊值],[通过列扫描])

第1参数：数组就是要转化成一行显示的数据

第2参数：忽略特殊值

如果输入0：不忽略特殊值

输入1：忽略空白单元格

输入2：忽略错误值

输入3：忽略空白单元格和错误值

第3参数：通过列扫描，FALSE，按行，TRUE按列，如果省略默认按行

一、基本应用（多行多列数据转换1行）

如下图所示，我们需要把左侧多行多列数据转换成一行

在目标单元格中输入公式

=TOROW(A2:F4,3,FALSE)

然后点击回车即可

解读：

①公式就是把A2:F4数据区域按行转换成一行数据，第2参数是3代表忽略空白单元格和错误值，第3参数是FALSE就是按行扫描。

②如果是想按列的转换的话，第3参数设置成TRUE即可，公式如下：

=TOROW(A2:F4,3,TRUE)

二、高级进阶用法（一对多查找）

如下图所示，我们想根据所属部门，查找对应的员工姓名，然后姓名按行排列。

方法1：TOROW+FILTER函数组合

在目标单元格中输入公式：

=TOROW(FILTER(B2:B8,C2:C8=E1,""),3)

然后点击回车，下拉填充即可。

解读：

公式中新使用FILTER函数根据条件查询出数据，然后再使用TOROW函数把查询结果转换成一行显示，TOROW函数第2参数是3，代表忽略空白单元格和错误值。

方法2：TOROW+IF函数组合

在目标单元格中输入公式：

=TOROW(IF(C2:C8=E1,B2:B8,NA()),3)

然后点击回车，下拉填充即可。

解读：

公式中首先使用IF判断函数，判断员工是否属于对应部门，如果是返回姓名，否则返回错误值（NA函数会把不符号条件的数据全部转换成错误值）；然后再使用TOROW函数把查询结果转换成一行显示，TOROW函数第2参数是3，代表忽略空白单元格和错误值。

三、高级进阶用法（多条件查找）

如下图所示，我们要根据“姓名”+“部门”2个条件，查询对应员工的“销售业绩”

在目标单元格中输入公式：

=TOROW(IF($B$2:$B$8&$C$2:$C$8=F2&G2,$D$2:$D$8,NA()),3)

然后点击回车，下拉填充即可。

解读：

这个公式的作用是在B列和C列中查找与F2和G2单元格内容相匹配的数据，然后返回D列中对应位置的值，并将这些值转换为一行显示。

1、IF函数：这是公式的主要部分，用于判断条件。$B$2:$B$8&$C$2:$C$8=F2&G2是判断条件，它检查范围B2:B8和C2:C8中的每个单元格连接起来是否等于F2和G2单元格的内容连接起来的字符串。

①连接字符串：$B$2:$B$8&$C$2:$C$8表示将B列和C列对应单元格的内容连接起来，形成一个新的字符串。例如，如果B2是"王晓"，C2是"业务部"，那么连接后的字符串就是"王晓业务部"。

②条件判断：F2&G2是将F2和G2单元格的内容连接起来，与B列和C列的连接字符串进行比较。如果它们相等，那么IF函数返回真（TRUE），否则返回假（FALSE）。

③返回值：如果条件为真，IF函数返回$D$2:$D$8中对应位置的值；如果条件为假，则返回NA()（NA函数会把不符号条件的数据全部转换成错误值）。

2、TOROW函数：使用TOROW函数把查询结果转换成一行显示，TOROW函数第2参数是3，代表忽略空白单元格和错误值。

四、高级进阶用法（多条件查找返回多列数据）

如下图所示，我们还是根据“姓名”+“部门”2个条件，但是返回的是“销售业绩”、“工龄”、“工资”这3列数据。

在目标单元格中输入公式：

=TOROW(IF($B$2:$B$8&$C$2:$C$8=H2&I2,$D$2:$F$8,NA()),3)

然后点击回车，下拉填充即可。

解读：

公式原理跟多条件查找一样，只是返回结果选择多列$D$2:$F$8即可。

以上就是【桃大喵学习记】今天的干货分享~觉得内容对你有所帮助，别忘了动动手指点个赞哦~。大家有什么问题欢迎关注留言，期待与你的每一次互动，让我们共同成长！